Statistics
| Revision:

root / configure.in @ 3317

History | View | Annotate | Download (14.5 KB)

1
dnl Process this file with autoconf to produce a configure script.
2
AC_PREREQ(2.50)
3
AC_INIT(src/main.c)
4
PACKAGE=sylpheed
5

    
6
dnl version number
7
MAJOR_VERSION=3
8
MINOR_VERSION=4
9
MICRO_VERSION=0
10
INTERFACE_AGE=0
11
BINARY_AGE=0
12
EXTRA_VERSION=beta7
13
BUILD_REVISION=1152
14
VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION$EXTRA_VERSION
15

    
16
dnl define if this is a development release
17
DEVEL_VERSION=1
18

    
19
dnl set $target
20
AC_CANONICAL_SYSTEM
21

    
22
dnl
23
AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
24
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
25
dnl AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
26
dnl AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
27
AC_SUBST(PACKAGE)
28
AC_SUBST(VERSION)
29
AC_SUBST(MAJOR_VERSION)
30
AC_SUBST(MINOR_VERSION)
31
AC_SUBST(MICRO_VERSION)
32
AC_SUBST(EXTRA_VERSION)
33
AC_SUBST(BUILD_REVISION)
34

    
35
dnl development or release version
36
AC_SUBST(DEVEL_VERSION)
37
if test "x$DEVEL_VERSION" != "x"; then
38
  AC_DEFINE(DEVEL_VERSION, 1, [Define if this is a development release])
39
fi
40

    
41
dnl libtool versioning
42
LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
43
dnl LT_CURRENT=`expr 1 + $MICRO_VERSION - $INTERFACE_AGE`
44
dnl LT_REVISION=$INTERFACE_AGE
45
dnl LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`
46
LT_CURRENT=2
47
LT_REVISION=0
48
LT_AGE=1
49
AC_SUBST(LT_RELEASE)
50
AC_SUBST(LT_CURRENT)
51
AC_SUBST(LT_REVISION)
52
AC_SUBST(LT_AGE)
53

    
54
dnl Specify a header configuration file
55
AM_CONFIG_HEADER(config.h)
56

    
57
AM_MAINTAINER_MODE
58

    
59
dnl Checks for programs.
60
dnl AC_ARG_PROGRAM
61
AC_PROG_CC
62
AM_DISABLE_STATIC
63
AC_ISC_POSIX
64
AM_PROG_CC_STDC
65
AC_PROG_INSTALL
66
AC_PROG_LN_S
67
AC_PROG_MAKE_SET
68
AC_PROG_CPP
69
dnl AC_PROG_RANLIB
70
AM_PROG_LEX
71
AC_PROG_YACC
72
AM_PROG_LIBTOOL
73

    
74
SYLPHEED_ACLOCAL_INCLUDE(ac)
75

    
76
native_win32=no
77

    
78
case "$target" in
79
*-darwin*)
80
	CFLAGS="$CFLAGS -no-cpp-precomp -fno-common"
81
	LIBSYLPH_CFLAGS="$LIBSYLPH_CFLAGS -xobjective-c"
82
	;;
83
*-*-mingw*)
84
	native_win32=yes
85
	CFLAGS="$CFLAGS -mms-bitfields -mwindows"
86
	LIBS="$LIBS -lws2_32 -lwinmm"
87
	AC_CHECK_PROG(WINDRES, windres, windres)
88
	;;
89
esac
90

    
91
AC_SUBST(LIBSYLPH_CFLAGS)
92

    
93
AM_CONDITIONAL(NATIVE_WIN32, test "$native_win32" = "yes")
94

    
95
dnl Checks for libraries.
96
AM_PATH_GLIB_2_0(2.8.0,, AC_MSG_ERROR(Test for GLib failed. See the 'INSTALL' for help.), gobject gmodule)
97

    
98
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
99

    
100
AM_PATH_GTK_2_0(2.8.0,, AC_MSG_ERROR(Test for Gtk failed. See the 'INSTALL' for help.))
101

    
102
dnl --disable-deprecated switch for GTK2 purification
103
AC_ARG_ENABLE(deprecated, [  --disable-deprecated    Disable deprecated GTK functions. ],
104
			  [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"], [])
105

    
106
AC_SUBST(GTK_CFLAGS)
107
AC_SUBST(GTK_LIBS)
108

    
109
dnl checks for iconv
110
AM_ICONV
111

    
112
AC_CHECK_FUNCS(bind_textdomain_codeset)
113

    
114
dnl for gettext
115
ALL_LINGUAS="be bg cs da de el es et eu fi fr gl hr hu it ja ko lt nl pl pt_BR ro ru sk sl sr sv tr uk vi zh_CN zh_TW"
116
GETTEXT_PACKAGE=sylpheed
117
AC_SUBST(GETTEXT_PACKAGE)
118
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Define text domain.])
119

    
120
AM_GLIB_GNU_GETTEXT
121
dnl AM_GNU_GETTEXT
122
dnl AC_CHECK_FUNC(gettext, AC_CHECK_LIB(intl, gettext))
123

    
124
if test "x$DATADIRNAME" != "x"; then
125
	localedir='${prefix}/${DATADIRNAME}/locale'
126
else
127
	localedir='${datadir}/locale'
128
fi
129
AC_ARG_WITH(localedir,
130
	[  --with-localedir=DIR    Locale directory],
131
	[localedir="$withval"])
132
AC_SUBST(localedir)
133

    
134
manualdir='${datadir}/${PACKAGE}/manual'
135
AC_ARG_WITH(manualdir,
136
	[  --with-manualdir=DIR    Manual directory],
137
	[manualdir="$withval"])
138
AC_SUBST(manualdir)
139

    
140
faqdir='${datadir}/${PACKAGE}/faq'
141
AC_ARG_WITH(faqdir,
142
	[  --with-faqdir=DIR       FAQ directory],
143
	[faqdir="$withval"])
144
AC_SUBST(faqdir)
145

    
146
plugindir='${exec_prefix}/lib/${PACKAGE}/plugins'
147
AC_ARG_WITH(plugindir,
148
	[  --with-plugindir=DIR    Plug-in directory],
149
	[plugindir="$withval"])
150
AC_SUBST(plugindir)
151

    
152
themedir='${datadir}/${PACKAGE}/icons'
153
AC_ARG_WITH(themedir,
154
	[  --with-themedir=DIR     Icon theme directory],
155
	[themedir="$withval"])
156
AC_SUBST(themedir)
157

    
158
dnl GPGME is used to support OpenPGP 
159
AC_ARG_ENABLE(gpgme,
160
	[  --disable-gpgme         Disable GnuPG support using GPGME],
161
	[ac_cv_enable_gpgme=$enableval], [ac_cv_enable_gpgme=yes])
162
AC_MSG_CHECKING([whether to use GPGME])
163
if test $ac_cv_enable_gpgme = yes; then
164
	AC_MSG_RESULT(yes)
165
	AM_PATH_GPGME(1.0.0, AC_DEFINE(USE_GPGME, 1, Define if you use GPGME to support OpenPGP.),
166
		      [use_gpgme=no
167
		       ac_cv_enable_gpgme=no])
168
else
169
	AC_MSG_RESULT(no)
170
fi
171

    
172
dnl for JPilot support in addressbook
173
dnl no check for libraries; these are dynamically loaded
174
AC_ARG_ENABLE(jpilot,
175
	[  --enable-jpilot         Enable JPilot support [[default=no]]],
176
	[ac_cv_enable_jpilot=$enableval], [ac_cv_enable_jpilot=no])
177
AC_MSG_CHECKING([whether to use JPilot])
178
if test "$ac_cv_enable_jpilot" = yes; then
179
	AC_MSG_RESULT(yes)
180
	AC_CHECK_HEADERS(pi-args.h pi-appinfo.h pi-address.h,
181
			 [ AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ],
182
			 [ ac_cv_enable_jpilot=no ])
183
	if test "$ac_cv_enable_jpilot" = no; then
184
		AC_CHECK_HEADERS(libpisock/pi-args.h libpisock/pi-appinfo.h libpisock/pi-address.h,
185
				 [ ac_cv_enable_jpilot=yes
186
				   AC_DEFINE(USE_JPILOT, 1, Define if you want JPilot support in addressbook.) ])
187
	fi
188
	AC_MSG_CHECKING([whether jpilot is available])
189
	AC_MSG_RESULT($ac_cv_enable_jpilot)
190

    
191
	if test "$ac_cv_enable_jpilot" = yes; then
192
		LIBS="$LIBS -lpisock"
193
	fi
194
else
195
	AC_MSG_RESULT(no)
196
fi
197

    
198
dnl for LDAP support in addressbook
199
dnl no check for libraries; dynamically loaded
200
AC_ARG_ENABLE(ldap,
201
	[  --enable-ldap           Enable LDAP support [[default=no]]],
202
	[ac_cv_enable_ldap=$enableval], [ac_cv_enable_ldap=no])
203
AC_MSG_CHECKING([whether to use LDAP])
204
if test "$ac_cv_enable_ldap" = yes; then
205
	AC_MSG_RESULT(yes)
206

    
207
	dnl check for available libraries, and pull them in
208
	AC_CHECK_LIB(resolv, res_query, LDAP_LIBS="$LDAP_LIBS -lresolv")
209
	AC_CHECK_LIB(socket, bind, LDAP_LIBS="$LDAP_LIBS -lsocket")
210
	AC_CHECK_LIB(nsl, gethostbyaddr, LDAP_LIBS="$LDAP_LIBS -lnsl")
211
	AC_CHECK_LIB(lber, ber_get_tag, LDAP_LIBS="$LDAP_LIBS -llber",,
212
		     $LDAP_LIBS)
213

    
214
	dnl we need libpthread for sylpheed ldap,  until we find
215
	dnl a better way to handle ldap requests asynchronously...
216
	AC_CHECK_LIB(pthread, pthread_create, LDAP_LIBS="$LDAP_LIBS -lpthread")
217

    
218
	AC_CHECK_HEADERS(ldap.h lber.h pthread.h,
219
			 [ ac_cv_enable_ldap=yes ],
220
			 [ ac_cv_enable_ldap=no ])
221

    
222
	if test "$ac_cv_enable_ldap" = yes; then
223
		AC_CHECK_LIB(ldap, ldap_open,
224
			     [ ac_cv_enable_ldap=yes ],
225
			     [ ac_cv_enable_ldap=no ],
226
			     $LDAP_LIBS)
227
	fi
228

    
229
	AC_MSG_CHECKING([whether ldap library is available])
230
	AC_MSG_RESULT($ac_cv_enable_ldap)
231

    
232
	if test "$ac_cv_enable_ldap" = yes; then
233
		CFLAGS="$CFLAGS `$PKG_CONFIG --cflags gthread-2.0`"
234
		LDAP_LIBS="$LDAP_LIBS -lldap `$PKG_CONFIG --libs gthread-2.0`"
235
		AC_DEFINE(USE_LDAP, 1, Define if you want LDAP support in addressbook.)
236
		AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
237
		AC_SUBST(LDAP_LIBS)
238
	fi
239
else
240
	AC_MSG_RESULT(no)
241
fi
242

    
243
dnl Check for OpenSSL
244
AC_ARG_ENABLE(ssl,
245
	[  --disable-ssl           Disable SSL support using OpenSSL],
246
	[ac_cv_enable_ssl=$enableval], [ac_cv_enable_ssl=yes])
247
AC_MSG_CHECKING([whether to use OpenSSL])
248
if test $ac_cv_enable_ssl = yes; then
249
	AC_MSG_RESULT(yes)
250
	dnl First check with pkg-config
251
	PKG_CHECK_MODULES(OPENSSL, openssl, [:], [:])
252
	if test "x$OPENSSL_LIBS" != "x"; then
253
		CFLAGS="$CFLAGS $OPENSSL_CFLAGS"
254
		LIBS="$LIBS $OPENSSL_LIBS"
255
		AC_MSG_CHECKING([if openssl is available])
256
		AC_MSG_RESULT(yes)
257
		AC_DEFINE(USE_SSL, 1, Define if you use OpenSSL to support SSL.)
258
	else
259
		dnl If pkg-config fails, run compile/link test.
260
		AC_MSG_CHECKING([if openssl is available])
261
		ac_save_LIBS="$LIBS"
262
		if test "$native_win32" = yes; then
263
			LIBS="$LIBS -lssl32 -leay32"
264
		else
265
			LIBS="$LIBS -lssl -lcrypto"
266
		fi
267
		AC_TRY_LINK([
268
#include <openssl/opensslv.h>
269
],		[ return OPENSSL_VERSION_NUMBER; ],
270
		[ AC_MSG_RESULT(yes)
271
		  AC_DEFINE(USE_SSL, 1, Define if you use OpenSSL to support SSL.) ],
272
		[ AC_MSG_RESULT(no)
273
		  LIBS="$ac_save_LIBS"
274
		  ac_cv_enable_ssl=no ])
275
	fi
276
else
277
	AC_MSG_RESULT(no)
278
fi
279

    
280
dnl Check for X-Face support
281
AC_ARG_ENABLE(compface,
282
	[  --disable-compface      Do not use compface (X-Face)],
283
	[ac_cv_enable_compface=$enableval], [ac_cv_enable_compface=yes])
284
if test "$ac_cv_enable_compface" = yes; then
285
	AC_CHECK_LIB(compface, uncompface,,[ac_cv_enable_compface=no])
286
fi
287

    
288
dnl Check for GtkSpell support
289
AC_MSG_CHECKING([whether to use GtkSpell])
290
AC_ARG_ENABLE(gtkspell,
291
	[  --disable-gtkspell      Do not use GtkSpell in editor],
292
	[ac_cv_enable_gtkspell=$enableval], [ac_cv_enable_gtkspell=yes])
293
if test "$ac_cv_enable_gtkspell" = yes; then
294
	AC_MSG_RESULT(yes)
295
	AC_MSG_CHECKING([whether GtkSpell is available])
296
	if $PKG_CONFIG gtkspell-2.0 ; then
297
		AC_MSG_RESULT(yes)
298
		CFLAGS="$CFLAGS `$PKG_CONFIG --cflags gtkspell-2.0`"
299
		LIBS="$LIBS `$PKG_CONFIG --libs gtkspell-2.0`"
300
		if $PKG_CONFIG --atleast-version 2.0.13 gtkspell-2.0 ; then
301
			AC_DEFINE(USE_ENCHANT, 1, Use Enchant with GtkSpell)
302
			LIBS="$LIBS `$PKG_CONFIG --libs enchant`"
303

    
304
			dnl Workaroud for zemberek crash
305
			if $PKG_CONFIG --atleast-version 1.4.2 enchant ; then
306
				CFLAGS="$CFLAGS `$PKG_CONFIG --cflags dbus-glib-1`"
307
				LIBS="$LIBS `$PKG_CONFIG --libs dbus-glib-1`"
308
			fi
309
		elif $PKG_CONFIG --atleast-version 2.0.12 gtkspell-2.0 ; then
310
			LIBS="$LIBS -laspell"
311
		fi
312
		AC_DEFINE(USE_GTKSPELL, 1, Use GtkSpell in editor)
313
	else
314
		AC_MSG_RESULT(no)
315
		ac_cv_enable_gtkspell=no
316
	fi
317
else
318
	AC_MSG_RESULT(no)		
319
fi
320

    
321
dnl Check for Oniguruma support in message filtering
322
AC_ARG_ENABLE(oniguruma,
323
	[  --enable-oniguruma      Use Oniguruma instead of system's regex [[default=no]]],
324
	[ac_cv_enable_oniguruma=$enableval], [ac_cv_enable_oniguruma=no])
325
AC_MSG_CHECKING([whether to use Oniguruma])
326
if test "$ac_cv_enable_oniguruma" = yes; then
327
	AC_MSG_RESULT(yes)
328
	AC_MSG_CHECKING([whether Oniguruma is available])
329
        dnl AC_CHECK_PROG(ONIG_CONFIG, onig-config, onig-config)
330
	ONIG_CONFIG=onig-config
331
	ONIG_VERSION=`$ONIG_CONFIG --version 2>/dev/null`
332
	if test "x$ONIG_VERSION" != "x"; then
333
		AC_MSG_RESULT(yes)
334
		CFLAGS="$CFLAGS `$ONIG_CONFIG --cflags`"
335
		LIBS="$LIBS `$ONIG_CONFIG --libs`"
336
		AC_DEFINE(USE_ONIGURUMA, 1, Define if you want to use Oniguruma.)
337
	else
338
		AC_MSG_RESULT(no)
339
		ac_cv_enable_oniguruma=no
340
	fi
341
else
342
	AC_MSG_RESULT(no)
343
fi
344

    
345
dnl check additional libraries
346
AC_CHECK_LIB(xpg4, setlocale)
347
AC_CHECK_LIB(resolv, res_init)
348
AC_CHECK_LIB(socket, bind)
349
AC_CHECK_LIB(nsl, gethostbyname)
350

    
351
dnl for GThread support
352
AC_ARG_ENABLE(threads,
353
	[  --disable-threads       Disable multithread support],
354
	[use_threads=$enableval], [use_threads=yes])
355

    
356
AC_MSG_CHECKING([whether to use threads])
357
if test x"$use_threads" = xyes ; then
358
	AC_MSG_RESULT(yes)
359
	if $PKG_CONFIG --exists gthread-2.0 ; then
360
		CFLAGS="$CFLAGS `$PKG_CONFIG --cflags gthread-2.0`"
361
		LIBS="$LIBS `$PKG_CONFIG --libs gthread-2.0`"
362
		AC_DEFINE(USE_THREADS, 1, Whether to use multithread or not)
363
	else
364
		AC_MSG_ERROR([Sylpheed requires GThread from GLib to enable threading.])
365
	fi
366
else
367
	AC_MSG_RESULT(no)
368
fi
369

    
370
dnl check for IPv6 option
371
AC_ARG_ENABLE(ipv6,
372
	[  --disable-ipv6          Disable IPv6 support],
373
	[ac_cv_enable_ipv6=$enableval], [ac_cv_enable_ipv6=yes])
374

    
375
dnl automated checks for IPv6 support.
376
AC_MSG_CHECKING([whether to use IPv6])
377
if test x"$ac_cv_enable_ipv6" = xyes; then
378
	AC_MSG_RESULT(yes)
379
	AC_MSG_CHECKING([for IPv6 support])
380
	if test "$native_win32" = yes; then
381
		AC_CACHE_VAL(ac_cv_ipv6,[
382
			AC_TRY_COMPILE([#define INET6
383
					#include <sys/types.h>
384
					#include <winsock2.h>
385
					#include <ws2tcpip.h>],
386
				[int x = IPPROTO_IPV6; struct in6_addr a;],
387
				ac_cv_ipv6=yes, ac_cv_ipv6=no)
388
		])
389
	else
390
		AC_CACHE_VAL(ac_cv_ipv6,[
391
			AC_TRY_COMPILE([#define INET6
392
					#include <sys/types.h>
393
					#include <netinet/in.h>],
394
				[int x = IPPROTO_IPV6; struct in6_addr a;],
395
				ac_cv_ipv6=yes, ac_cv_ipv6=no)
396
		])
397
	fi
398
	AC_MSG_RESULT($ac_cv_ipv6)
399
	if test $ac_cv_ipv6 = yes; then
400
		AC_DEFINE(INET6, 1, Define if you want IPv6 support.)
401
	else
402
		AC_MSG_WARN(*** IPv6 will not be supported ***)
403
		ac_cv_enable_ipv6=no
404
	fi
405
else
406
	AC_MSG_RESULT(no)
407
fi
408

    
409
dnl for update check feature
410
AC_ARG_ENABLE(updatecheck,
411
	[  --disable-updatecheck   Disable update check feature],
412
	[ac_cv_enable_updatecheck=$enableval], [ac_cv_enable_updatecheck=yes])
413
if test x"$ac_cv_enable_updatecheck" = xyes ; then
414
	AC_DEFINE(USE_UPDATE_CHECK, 1, Define if you want update check feature.)
415

    
416
  dnl for update check feature (requires update check enabled)
417
  AC_ARG_ENABLE(updatecheckplugin,
418
	[  --disable-updatecheckplugin   Disable update check plugin feature],
419
	[ac_cv_enable_updatecheckplugin=$enableval], [ac_cv_enable_updatecheckplugin=yes])
420
  if test x"$ac_cv_enable_updatecheckplugin" = xyes ; then
421
	AC_DEFINE(USE_UPDATE_CHECK_PLUGIN, 1, Define if you want update check plugin feature.)
422
  fi
423
fi
424

    
425
dnl Check for d_type member in struct dirent
426
AC_MSG_CHECKING([whether struct dirent has d_type member])
427
AC_CACHE_VAL(ac_cv_dirent_d_type,[
428
	AC_TRY_COMPILE([#include <dirent.h>],
429
		       [struct dirent d; d.d_type = DT_REG;],
430
		       ac_cv_dirent_d_type=yes, ac_cv_dirent_d_type=no)
431
])
432
AC_MSG_RESULT($ac_cv_dirent_d_type)
433
if test $ac_cv_dirent_d_type = yes; then
434
	AC_DEFINE(HAVE_DIRENT_D_TYPE, 1,
435
		  Define if `struct dirent' has `d_type' member.)
436
fi
437

    
438

    
439
dnl Checks for header files.
440
AC_HEADER_DIRENT
441
AC_HEADER_STDC
442
AC_HEADER_SYS_WAIT
443
AC_CHECK_HEADERS(fcntl.h sys/file.h unistd.h paths.h \
444
		 sys/param.h sys/utsname.h sys/select.h \
445
		 netdb.h regex.h sys/mman.h)
446

    
447
dnl Checks for typedefs, structures, and compiler characteristics.
448
AC_C_CONST
449
AC_TYPE_OFF_T
450
AC_TYPE_PID_T
451
AC_TYPE_SIZE_T
452
AC_STRUCT_TM
453

    
454
AC_SYS_LARGEFILE
455
AC_FUNC_FSEEKO
456

    
457
GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF, Used to test for a u32 typedef)
458
AC_CHECK_SIZEOF(unsigned short, 2)
459
AC_CHECK_SIZEOF(unsigned int, 4)
460
AC_CHECK_SIZEOF(unsigned long, 4)
461

    
462
dnl Checks for library functions.
463
AC_FUNC_ALLOCA
464
AC_CHECK_FUNCS(gethostname mkdir mktime socket strstr strchr \
465
	       uname flock lockf inet_aton inet_addr \
466
	       fchmod truncate getuid regcomp mlock fsync)
467

    
468
AC_OUTPUT([
469
Makefile
470
sylpheed.spec
471
ac/Makefile
472
libsylph/Makefile
473
src/version.h
474
src/sylpheed.rc
475
src/Makefile
476
src/icons/Makefile
477
plugin/Makefile
478
plugin/attachment_tool/Makefile
479
plugin/test/Makefile
480
po/Makefile.in
481
faq/Makefile
482
faq/de/Makefile
483
faq/en/Makefile
484
faq/es/Makefile
485
faq/fr/Makefile
486
faq/it/Makefile
487
manual/Makefile
488
manual/en/Makefile
489
manual/ja/Makefile
490
nsis/Makefile
491
macosx/Makefile
492
macosx/bundle/Makefile
493
])
494

    
495
dnl Output the configuration summary
496
echo ""
497
echo "$PACKAGE $VERSION"
498
echo ""
499
echo "GnuPG         : $ac_cv_enable_gpgme"
500
echo "JPilot        : $ac_cv_enable_jpilot"
501
echo "LDAP          : $ac_cv_enable_ldap"
502
echo "OpenSSL       : $ac_cv_enable_ssl"
503
echo "iconv         : $am_cv_func_iconv"
504
echo "compface      : $ac_cv_enable_compface"
505
echo "IPv6          : $ac_cv_enable_ipv6"
506
echo "GtkSpell      : $ac_cv_enable_gtkspell"
507
echo "Oniguruma     : $ac_cv_enable_oniguruma"
508
echo "GThread       : $use_threads"
509
echo ""
510
echo "The binary will be installed in $prefix/bin"
511
echo ""
512
echo "Configure finished, type 'make' to build."